dnl AM_PATH_PERCGI([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
dnl Test for PerCGI, and define PERCGI_CFLAGS and PERCGI_LIBS
dnl
AC_DEFUN([AM_PATH_PERCGI],
[dnl 
dnl Get the cflags and libraries from the percgi-config script
dnl
AC_ARG_WITH(percgi-prefix,[  --with-percgi-prefix=PFX   Prefix where PerCGI is installed (optional)],
            percgi_prefix="$withval", percgi_prefix="")
AC_ARG_WITH(percgi-exec-prefix,[  --with-percgi-exec-prefix=PFX Exec prefix where PerCGI is installed (optional)],
            percgi_exec_prefix="$withval", percgi_exec_prefix="")
AC_ARG_ENABLE(percgitest, [  --disable-percgitest       Do not try to compile and run a test PerCGI program],
		    , enable_percgitest=yes)

  if test x$percgi_exec_prefix != x ; then
    percgi_config_args="$percgi_config_args --exec-prefix=$percgi_exec_prefix"
    if test x${PERCGI_CONFIG+set} != xset ; then
      PERCGI_CONFIG=$percgi_exec_prefix/bin/percgi-config
    fi
  fi
  if test x$percgi_prefix != x ; then
    percgi_config_args="$percgi_config_args --prefix=$percgi_prefix"
    if test x${PERCGI_CONFIG+set} != xset ; then
      PERCGI_CONFIG=$percgi_prefix/bin/percgi-config
    fi
  fi

  if test "x$prefix" != xNONE; then
    PATH="$prefix/bin:$prefix/usr/bin:$PATH"
  fi
  AC_PATH_PROG(PERCGI_CONFIG, percgi-config, no, [$PATH])
  min_percgi_version=ifelse([$1], ,0.11.0,$1)
  AC_MSG_CHECKING(for PerCGI - version >= $min_percgi_version)
  no_percgi=""
  if test "$PERCGI_CONFIG" = "no" ; then
    no_percgi=yes
  else
    PERCGI_CFLAGS=`$PERCGI_CONFIG $percgi_config_args --cflags`
    PERCGI_LIBS=`$PERCGI_CONFIG $percgi_config_args --libs`

    percgi_major_version=`$PERCGI_CONFIG $percgi_config_args --version | \
           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\).*/\1/'`
    percgi_minor_version=`$PERCGI_CONFIG $percgi_config_args --version | \
           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\).*/\2/'`
    percgi_micro_version=`$PERCGI_CONFIG $percgi_config_args --version | \
           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\).*/\3/'`
    if test "x$enable_percgitest" = "xyes" ; then
      ac_save_CFLAGS="$CFLAGS"
      ac_save_CXXFLAGS="$CXXFLAGS"
      ac_save_LIBS="$LIBS"
      CFLAGS="$CFLAGS $PERCGI_CFLAGS"
      CXXFLAGS="$CXXFLAGS $PERCGI_CFLAGS"
      LIBS="$LIBS $PERCGI_LIBS"
dnl
dnl Now check if the installed PerCGI is sufficiently new. (Also sanity
dnl checks the results of percgi-config to some extent
dnl
      rm -f conf.percgitest
      AC_TRY_RUN([
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <percgi/core.h>
#include <percgi/gui.h>

char*
my_strdup (char *str)
{
  char *new_str;
  
  if (str)
    {
      new_str = (char *)malloc ((strlen (str) + 1) * sizeof(char));
      strcpy (new_str, str);
    }
  else
    new_str = NULL;
  
  return new_str;
}

int main (int argc, char *argv[])
{
  int major, minor, micro;
  char *tmp_version;

  /* This hangs on some systems (?)
  system ("touch conf.percgitest");
  */
  { FILE *fp = fopen("conf.percgitest", "a"); if ( fp ) fclose(fp); }

  /* HP/UX 9 (%@#!) writes to sscanf strings */
  tmp_version = my_strdup("$min_percgi_version");
  if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
     printf("%s, bad version string\n", "$min_percgi_version");
     exit(1);
   }

   if (($percgi_major_version > major) ||
      (($percgi_major_version == major) && ($percgi_minor_version > minor)) ||
      (($percgi_major_version == major) && ($percgi_minor_version == minor) && ($percgi_micro_version >= micro)))
    {
      return 0;
    }
  else
    {
      printf("\n*** 'percgi-config --version' returned %d.%d.%d, but the minimum version\n", $percgi_major_version, $percgi_minor_version, $percgi_micro_version);
      printf("*** of PerCGI required is %d.%d.%d. If percgi-config is correct, then it is\n", major, minor, micro);
      printf("*** best to upgrade to the required version.\n");
      printf("*** If percgi-config was wrong, set the environment variable PERCGI_CONFIG\n");
      printf("*** to point to the correct copy of percgi-config, and remove the file\n");
      printf("*** config.cache before re-running configure\n");
      return 1;
    }
}

],, no_percgi=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
       CFLAGS="$ac_save_CFLAGS"
       CXXFLAGS="$ac_save_CXXFLAGS"
       LIBS="$ac_save_LIBS"
     fi
  fi
  if test "x$no_percgi" = x ; then
     AC_MSG_RESULT(yes)
     ifelse([$2], , :, [$2])     
  else
     AC_MSG_RESULT(no)
     if test "$PERCGI_CONFIG" = "no" ; then
       echo "*** The percgi-config script installed by PerCGI could not be found"
       echo "*** If PerCGI was installed in PREFIX, make sure PREFIX/bin is in"
       echo "*** your path, or set the PERCGI_CONFIG environment variable to the"
       echo "*** full path to percgi-config."
     else
       if test -f conf.percgitest ; then
        :
       else
          echo "*** Could not run PerCGI test program, checking why..."
          CFLAGS="$CFLAGS $PERCGI_CFLAGS"
          CXXFLAGS="$CXXFLAGS $PERCGI_CFLAGS"
          LIBS="$LIBS $PERCGI_LIBS"
          AC_TRY_LINK([
#include <stdio.h>
#include <percgi/core.h>
#include <percgi/gui.h>

int main(int argc, char *argv[])
{ return 0; }
#undef  main
#define main K_and_R_C_main
],      [ return 0; ],
        [ echo "*** The test program compiled, but did not run. This usually means"
          echo "*** that the run-time linker is not finding PerCGI or finding the wrong"
          echo "*** version of PerCGI. If it is not finding PerCGI, you'll need to set your"
          echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
          echo "*** to the installed location  Also, make sure you have run ldconfig if that"
          echo "*** is required on your system"
	  echo "***"
          echo "*** If you have an old version installed, it is best to remove it, although"
          echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
        [ echo "*** The test program failed to compile or link. See the file config.log for the"
          echo "*** exact error that occured. This usually means PerCGI was incorrectly installed"
          echo "*** or that you have moved PerCGI since it was installed. In the latter case, you"
          echo "*** may want to edit the percgi-config script: $PERCGI_CONFIG" ])
          CFLAGS="$ac_save_CFLAGS"
          CXXFLAGS="$ac_save_CXXFLAGS"
          LIBS="$ac_save_LIBS"
       fi
     fi
     PERCGI_CFLAGS=""
     PERCGI_LIBS=""
     ifelse([$3], , :, [$3])
  fi
  AC_SUBST(PERCGI_CFLAGS)
  AC_SUBST(PERCGI_LIBS)
  rm -f conf.percgitest
])